f



detecting when a form is moved.

I have a main form, and a child form. Just before the child form becomes is
shown, it gets moved to some position relative to the main form, and stays
on top of the main form with a call to the SetWindowPos API.

Question:    If the main form is then moved (dragged by the mouse), how can
I capture this and relocate the child appropriately? Preferably the child
would drag along with the parent as it is moved.

Is there a way to "lock" a child form's position relative to it's parent?

TIA!


0
none18 (402)
1/8/2005 12:25:54 AM
comp.lang.basic.visual.misc 10153 articles. 0 followers. Post Follow

7 Replies
369 Views

Similar Articles

[PageSpeed] 40

Question is a bit confusing. But, assuming the 'Child' Form is not the child 
of an MDIform, and it is a a form that is called by another form then the 
code below is a cheap and dirty way moving one form relative to another and 
locking it's aspect ratio (Ish  :-). It would need a lot of work to make it 
work well, but it should give you an idea.

Ivar

New Project. Two forms (Form1 and Form2)
Add a timer (Timer1) to Form1

Paste the code below in to Form1

Option Explicit

Const HWND_TOPMOST = -1
Const SWP_NOACTIVATE = &H10

Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Type POINTAPI
    X As Long
    Y As Long
End Type
Private Declare Function GetCursorPos Lib "user32" _
(lpPoint As POINTAPI) As Long
Private Declare Sub SetWindowPos Lib "user32" _
(ByVal hWnd As Long, ByVal hWndInsertAfter As Long, _
ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
ByVal cy As Long, ByVal wFlags As Long)
Private Declare Function GetWindowRect Lib "user32" _
(ByVal hWnd As Long, lpRect As RECT) As Long
Dim FormWidth As Integer
Dim FormHeight As Integer

Private Sub Form_Load()
Me.ScaleMode = vbPixels
'Me.Move 100, 100, 4500, 4500
Form2.Show
FormWidth = Me.Width / Screen.TwipsPerPixelX
FormHeight = Me.Height / Screen.TwipsPerPixelY
Timer1.Interval = 10
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
Unload Form2
Set Form2 = Nothing
End Sub

Private Sub Form_Resize()
FormWidth = Me.Width / Screen.TwipsPerPixelX
FormHeight = Me.Height / Screen.TwipsPerPixelY
End Sub

Private Sub Timer1_Timer()
'Move Form2 relative to the Size and Position of Form1
Dim Rec As RECT
GetWindowRect Me.hWnd, Rec
With Rec
..Left = .Left + 50
..Top = .Top + 50
..Right = (.Right - 100) - .Left
..Bottom = (.Bottom - 100) - .Top
SetWindowPos Form2.hWnd, HWND_TOPMOST, _
Rec.Left, _
Rec.Top, .Right, .Bottom, _
SWP_NOACTIVATE
End With
End Sub 


0
1/8/2005 2:40:38 AM
"calan" <none@nospam.com> wrote in message
news:mMFDd.13055$iC4.2147@newssvr30.news.prodigy.com...
| I have a main form, and a child form. Just before the child form
becomes is
| shown, it gets moved to some position relative to the main form, and
stays
| on top of the main form with a call to the SetWindowPos API.
|
| Question:    If the main form is then moved (dragged by the mouse),
how can
| I capture this and relocate the child appropriately? Preferably the
child
| would drag along with the parent as it is moved.
|
| Is there a way to "lock" a child form's position relative to it's
parent?
|
| TIA!
|

You might try using SetParent in the child form:

Private Declare Function SetParent Lib "user32.dll" ( _
     ByVal hWndChild As Long, _
     ByVal hWndNewParent As Long) As Long

Private Sub Command1_Click()
    Call SetParent(Me.hWnd, Form1.hWnd)
End Sub



0
mynamehere (1583)
1/8/2005 7:16:58 AM
"Steve Gerrard" <mynamehere@comcast.net> wrote in message
news:udadnVRGkf17FULcRVn-pQ@comcast.com...

> You might try using SetParent in the child form:
>
> Private Declare Function SetParent Lib "user32.dll" ( _
>      ByVal hWndChild As Long, _
>      ByVal hWndNewParent As Long) As Long
>
> Private Sub Command1_Click()
>     Call SetParent(Me.hWnd, Form1.hWnd)
> End Sub
>


Thanks Steve...worked beautifully!

Couple of questions:

1. Is this API function supported across all os (98 and higher)?

2. When the child form is activated (controls are clicked), is there any way
to make things appear as if the parent form never loses focus? As if the
child form was just another control, and the title bar of the parent stays
active?

Thanks...


0
none18 (402)
1/8/2005 9:38:42 AM
I don't get it...  This isn't working perfectly, now Form1 just works as an 
MDI form and Form2 as a MDIChild?  This means that I can move Form2 out of 
sight, because it simply is contained "within" Form1.  And besides, you 
don't have to call any API to make a Form2 topmost over Form1, you simply 
show Form2 using "Form2.Show vbModeless, Form1", which automatically makes 
Form2 a "child" (non-modal) of Form1....  Hm.

If that is the effect you want, then everyone is happy I guess...  But if 
one just wants to have a second window following the main window, pretty 
much as a floating toolbar would, then this method is not appropriate. 
Especially since you can't even resize Form1 without the risk of Form2 
wanishing.  :-)

But this is interesting, is there anyone here that knows how to do this, to 
make a second window follow another window when that one is moved?

Thanks in advance,

Steinar



"calan" <none@nospam.com> wrote in message 
news:CSNDd.13294$iC4.9848@newssvr30.news.prodigy.com...
>
> "Steve Gerrard" <mynamehere@comcast.net> wrote in message
> news:udadnVRGkf17FULcRVn-pQ@comcast.com...
>
>> You might try using SetParent in the child form:
>>
>> Private Declare Function SetParent Lib "user32.dll" ( _
>>      ByVal hWndChild As Long, _
>>      ByVal hWndNewParent As Long) As Long
>>
>> Private Sub Command1_Click()
>>     Call SetParent(Me.hWnd, Form1.hWnd)
>> End Sub
>>
>
>
> Thanks Steve...worked beautifully!
>
> Couple of questions:
>
> 1. Is this API function supported across all os (98 and higher)?
>
> 2. When the child form is activated (controls are clicked), is there any 
> way
> to make things appear as if the parent form never loses focus? As if the
> child form was just another control, and the title bar of the parent stays
> active?
>
> Thanks...
>
> 


0
leebouf (57)
1/8/2005 12:42:46 PM
"Steinar" <leebouf@hotmail.com> wrote in message
news:ezQDd.3352$IW4.73326@news2.e.nsc.no...
| I don't get it...  This isn't working perfectly, now Form1 just works
as an
| MDI form and Form2 as a MDIChild?  This means that I can move Form2
out of
| sight, because it simply is contained "within" Form1.  And besides,
you
| don't have to call any API to make a Form2 topmost over Form1, you
simply
| show Form2 using "Form2.Show vbModeless, Form1", which automatically
makes
| Form2 a "child" (non-modal) of Form1....  Hm.
|
| If that is the effect you want, then everyone is happy I guess...  But
if
| one just wants to have a second window following the main window,
pretty
| much as a floating toolbar would, then this method is not appropriate.

My toolbars either move with the window, and never go outside its
boundaries (i.e. are docked), or they float on their own, and don't move
with the window. I don't know that you can have a window tied to another
while positioned outside of it.

I agree, the
    Form2.Show vbModeless, Form1
makes sense as the way to open it.

SetParent is still useful, since you can toggle the child state of the
window with it.

And to the OP: MSDN says SetParent is a Win95 or later API.




0
mynamehere (1583)
1/8/2005 6:33:16 PM
' bas code:
Public Const GWL_WNDPROC As Long = (-4)
Public Const WM_NCHITTEST = &H84
Public Const WM_NCMOUSEMOVE = &HA0
Public Const WM_NCRBUTTONDOWN = &HA4
Public Const WM_NCRBUTTONUP = &HA5
Public Const WM_NCLBUTTONDOWN = &HA1
Public Const WM_NCLBUTTONUP = &HA2

Private Const WM_MOVING As Long = &H216

Public defWindowProc As Long

Public Declare Function SetWindowLong Lib "user32" _
    Alias "SetWindowLongA" _
   (ByVal hwnd As Long, _
    ByVal nIndex As Long, _
    ByVal dwNewLong As Long) As Long

Public Declare Function CallWindowProc Lib "user32" _
    Alias "CallWindowProcA" _
   (ByVal lpPrevWndFunc As Long, _
    ByVal hwnd As Long, _
    ByVal uMsg As Long, _
    ByVal wParam As Long, _
    ByVal lParam As Long) As Long

Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Public Const SWP_NOMOVE = &H2
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOACTIVATE = &H10
Public Const SWP_SHOWWINDOW = &H40
Public Const FLAGS = SWP_NOMOVE Or SWP_NOSIZE

Public Declare Function SetWindowPos _
    Lib "user32" _
   (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
    ByVal x As Long, ByVal y As Long, _
    ByVal cx As Long, ByVal cy As Long, _
    ByVal wFlags As Long) As Long


Public Sub SubClass(hwnd As Long)

   defWindowProc = SetWindowLong(hwnd, _
                                 GWL_WNDPROC, _
                                 AddressOf WindowProc)

End Sub


Public Sub UnSubClass(hwnd As Long)

   If defWindowProc Then
      SetWindowLong hwnd, GWL_WNDPROC, defWindowProc
      defWindowProc = 0
   End If

End Sub


Public Function WindowProc(ByVal hwnd As Long, _
                           ByVal uMsg As Long, _
                           ByVal wParam As Long, _
                           ByVal lParam As Long) As Long

   Select Case hwnd

      Case frmMain.hwnd

         Select Case uMsg

            Case WM_MOVING

               Form1.Move (frmMain.Left + frmMain.Width), frmMain.Top

              Case Else

          End Select

   End Select

   WindowProc = CallWindowProc(defWindowProc, _
                               hwnd, _
                               uMsg, _
                               wParam, _
                               lParam)

End Function



' frmMain code
Private Sub cndEnd_Click()

   Unload Me

End Sub


Private Sub Form_Load()

  'make top-most
   Call SetWindowPos(Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS)

  'subclass
   Call SubClass(frmMain.hwnd)

   Form1.Show  'the tagalong form

End Sub


Private Sub Form_Unload(Cancel As Integer)

    Call UnSubClass(Me.hwnd)

End Sub


Adjust the values in windowproc as required to position where you want. If 
you want the relative position maintained, use GetWindowRect and 
ScreenToClient to obtain the current and new positions for the tagalong 
form.

This coe presumes you are NOT asking for MDI code -- this for SDI apps only.


-- 


Randy Birch
MS MVP Visual Basic
http://vbnet.mvps.org/


"Steve Gerrard" <mynamehere@comcast.net> wrote in message 
news:LKydnW3Gm5D6un3cRVn-ow@comcast.com...
:
: "Steinar" <leebouf@hotmail.com> wrote in message
: news:ezQDd.3352$IW4.73326@news2.e.nsc.no...
: | I don't get it...  This isn't working perfectly, now Form1 just works
: as an
: | MDI form and Form2 as a MDIChild?  This means that I can move Form2
: out of
: | sight, because it simply is contained "within" Form1.  And besides,
: you
: | don't have to call any API to make a Form2 topmost over Form1, you
: simply
: | show Form2 using "Form2.Show vbModeless, Form1", which automatically
: makes
: | Form2 a "child" (non-modal) of Form1....  Hm.
: |
: | If that is the effect you want, then everyone is happy I guess...  But
: if
: | one just wants to have a second window following the main window,
: pretty
: | much as a floating toolbar would, then this method is not appropriate.
:
: My toolbars either move with the window, and never go outside its
: boundaries (i.e. are docked), or they float on their own, and don't move
: with the window. I don't know that you can have a window tied to another
: while positioned outside of it.
:
: I agree, the
:    Form2.Show vbModeless, Form1
: makes sense as the way to open it.
:
: SetParent is still useful, since you can toggle the child state of the
: window with it.
:
: And to the OP: MSDN says SetParent is a Win95 or later API.
:
:
:
: 

0
1/8/2005 7:16:10 PM
Hm.  This is pretty neat...

I've been playing with this a lot now (the whole evening in fact), really 
useful stuff - and a real brain teaser if one just extends the box a little 
(I don't dare thinking outside of it yet)!  :-)

Thank you Randy, learned a lot from this one.

Steinar 


0
leebouf (57)
1/9/2005 1:11:07 AM
Reply:

Similar Artilces:

Accessing data from one form from main form in Visual Basic 6
How do I extract data from a form into the main form for processing? For instance, I have several image files in a form called images(images.frm), indexed from 0 to 99, and I want to import these into a variable array in my main form, main (form1.frm). How do I code a control to get these images into an array in my main form from the images.frm? TIA JC wrote: > How do I extract data from a form into the main form for > processing? For instance, I have several image files in a > form called images(images.frm), indexed from 0 to 99, and > I want to import these into a variable...

moving Visual Basic to OREXX
Hi, I'm switching a little application from VB to OREXX, but I need some help. What is the equivalent codesequence in OREXX for the VB statement: Declare Function myFunc Lib "c:\test.dll" (Byval int01 as integer, Byval line as string) as integer Thank you. Hi opa, opaque schrieb: > I'm switching a little application from VB to OREXX, > but I need some help. > What is the equivalent codesequence in OREXX for the > VB statement: > > Declare Function myFunc Lib "c:\test.dll" (Byval int01 as integer, Byval > line as string) as integer > ...

Browser for visual basic forms
I am in search for a browser to see all my visual basic forms without starting every time visual basic and the project. Where can i find one ? Sorry for my English. Thanks Look to Notepad HE "Laurent" <Jan.Laurent@Pandora.be> schreef in bericht news:414336AA.2B843C1F@Pandora.be... > I am in search for a browser to see all my visual basic forms without > starting every time visual basic and the project. > Where can i find one ? > > Sorry for my English. > > Thanks I wil look at the graphic form, not de code behind. jan Never heard of such a browser. Can't be better then VB itselfs. But ... make a hardcopy of all your forms, then you can look at the individual forms with Paint :) HE "Laurent" <Jan.Laurent@Pandora.be> schreef in bericht news:41437552.CC900994@Pandora.be... > I wil look at the graphic form, not de code behind. > > jan What I do is get the form on screen and press "Print Screen" to save it to the clip board. Then I open Note Pad to view and/or print a paper copy. Jim Y "Laurent" <Jan.Laurent@Pandora.be> wrote in message news:414336AA.2B843C1F@Pandora.be... >I am in search for a browser to see all my visual basic forms without > starting every time visual basic and the project. > Where can i find one ? > > Sorry for my English. > > Thanks Jim Y Top-posted: > What I do is get the form on screen and press "Print Screen" ...

Visual Objects compared to Visual Basic and Visual C.
Who can explain me why I have to use VO instead of VB or VC? OR is is there no difference? With kind regards Rob van der Ploeg Rob, Every language has his (dis)advantages. The ones you mention are all wrappers around the Win32 API. VO is a very nice and easy language compared to VC. Data-access is famous with VO, but also memorymanagement, the cargage collector, ragged array's. and the result is fast and reliable code. You do not have to declare every variable if you do not want to. (but you will) Comparing to VB is VO a real OOP langangue where VB is not. You can write your own classes, inherit classes from VO classes or from your own classes, Overide methods, use both strong and loose typed variables, write early and late bound code VO comes with a SDK containing the sourcecode of the part of VO written in VO (almost everything except f.i. the compiler) With VO you get this newsgroup, where almost every question is answered within hours. VO has a prof. usergroup in the netherlands, check www.sdgn.nl. with very often very well organised conferences. I think it is the best organised usergroup in the world. VO is limitted to the Win32 api. A .NET version is announced, but withoot a releasedate yet. More inforrmation about VO can be found at www.cavo.com regards, Erik "Mobi-Data Helpdesk" <info@direcom.nl> schreef in bericht news:1070360435.358105@tbird.introweb.nl... > Who can explain me why I have to use...

Import forms from Visual Basic into Access
Hello Can anybody tell me, whether it is possible to import (simple) forms from Visual Basic into Access? Thanks a lot. Beat I haven't seen any tools that can do this. Most tools try to go the other way. Sorry. ...

GW BASIC to Visual Basic
I had done programnming in GW BASIC and Assembly 10 years back, when I was in school. Later, I learnt C,C++, Core Java and COBOL. Will my knowledge of BASIC hold me in good stead while learning Visual Basic? Is there a resemblance between the two? On 2 Mar 2005 21:11:59 -0800, "cat_dog_ass" <icon_iconoclast@hotmail.com> wrote: >I had done programnming in GW BASIC and Assembly 10 years back, when I >was in school. Later, I learnt C,C++, Core Java and COBOL. Will my >knowledge of BASIC hold me in good stead while learning Visual Basic? >Is there a resemblance between the two? A resemblance? Well, sure, they both look like Microsoft BASIC. Will knowing the one help with the other? Actually, the differences between GWB and VB are so big that you'll be learning a totally new language that reminds you of one you already know. If you learn VB.Net you might find that it also reminds you of C++ and/or Java. -- auric underscore underscore at hotmail dot com ***** If at first you don't succeed, skydiving is not for you. "cat_dog_ass" <icon_iconoclast@hotmail.com> wrote in message news:1109826719.850575.113070@o13g2000cwo.googlegroups.com... > I had done programnming in GW BASIC and Assembly 10 years > back, when I was in school . . . will my knowledge of BASIC hold > me in good stead while learning Visual Basic? If you're talking about VB6 then then answer is Yes. Much of the syntax of the language is almost iden...

OT: NET visual basic Main menu,forms
Sorry for the off topic but which group would you recomend for questions about .NET Visual Basic? I have some beginners questions and i need some help. I'm going to ask them here so if someone can help me I would apriciate that. This are questions for the .NET Visual Basic program:not integrated in access. How can I make a form in ..NET visual basic and open it from another form because i know how to make a main form but i cant make other forms. Or is there a way to open a new form from the main menu? How can i work with the main menu? I would like to make a menu on my main form and i would like to have one menu let's say that has: Main,Screen1,Screen2...Screen5 and Exit. When I click on Screen1...5 the a new form would open instead of the main form, and when I would click Main the main form would open insted of the current form. How can I do that? Please help or just point me to a god news group or web page! Thanks Bojan bojan.sekoranja@gmail.com wrote: > Sorry for the off topic but which group would you recomend for > questions about .NET Visual Basic? > I have some beginners questions and i need some help. > I'm going to ask them here so if someone can help me I would apriciate > that. > This are questions for the .NET Visual Basic program:not integrated > in access. Try http://groups.google.com/group/microsoft.public.dotnet.languages.vb?hl=en Edward ...

Visual Basic 6.0 form design issue
When I attempt to open a form in design mode, the form does not display. Some forms in the project open correctly, but others do not display. This started after I re-installed my windows XP system and reinstalled Visual Basic 6.0. I thought I might be missing some controls, but there is not an error when the project is loaded. If I build the project and run it, not a problem displaying the form in run-time. Thank You for any help with this! "Jay Fischer" <jayfischer@cox.net>'s wild thoughts were released on Mon, 3 Sep 2007 10:17:05 -0500 bearing the following fruit: >When I attempt to open a form in design mode, the form does not display. >Some forms in the project open correctly, but others do not display. This >started after I re-installed my windows XP system and reinstalled Visual >Basic 6.0. I thought I might be missing some controls, but there is not an >error when the project is loaded. If I build the project and run it, not a >problem displaying the form in run-time. > >Thank You for any help with this! > It may be positioned off screen. Delete the .vbw file and reopen, if that still doesn't work, press F4 and change the left and top properties. -- Jan Hyde https://mvp.support.microsoft.com/profile/Jan.Hyde Thank you for this info. It was the left property set way out to the right. I don't know why I didn't catch that sometimes everyone needs a little help. "Jan Hyde (VB MVP)&...

Power Builder Vs Visual Basic Vs Oracle forms
I need a good independent paper on what to use for software development tools such as, Power Builder Vs Visual basic or Power Builder Vs Oracle Form, or Oracle forms Vs Visual Basic. I appreciate your help in this matter Email me at elsheik@canada.com ...

cd 4 "visual basic lang. developers handbook"
Hi I need the cd that came with this book. visual basic language developers handbook ISBN 0-7821-2162-4 I lost it or it was stolen or whatever. Any help would be welcome. Can you burn me a copy, zip it and send it, whatever. mail to : rbm@bellsouth.net thanks Did ya call the publisher? I think they'll send you a new CD for a nominal fee... or you might be able to download it. Not sure. It's been a while since I had to do something like that. Bob wrote: > Hi > I need the cd that came with this book. > > visual basic language > developers handbook > ISBN 0-7821-2162-4 > > I lost it or it was stolen or whatever. Any help would be welcome. > Can you burn me a copy, zip it and send it, whatever. > > mail to : rbm@bellsouth.net Book available on Amazon as http://www.amazon.com/exec/obidos/ASIN/0782121624/ and the author's website has 3 chapters available and perhaps some code: http://www.developershandbook.com/downloads.htm and the book's Errata: http://www.developershandbook.com/ErrataVBLanguage.htm -- '--------------- 'John Mishefske '--------------- ...

Adding a New Record to Access form using Visual Basic in Excel
I am searching for a way to create multiple records in Access 2000 from a worksheet created in Excel. I'm pretty much self-taught with Visual Basic so forgive me if this poorly described. Basically what happens is, from Access, while in Form1, I click a button that opens Excel and my worksheet. This worksheet contains a button with the following code ( I've replaced the sections where I assign cell values to the variables with ellipses): Dim oAcc As Object ... Set oAcc = GetObject(, "Access.Application") ... If oAcc.Forms!Form1.NewRecord = True Then ' check to ensure I don't write over old data oAcc.Forms!Form1![Amount] = curTotal oAcc.Forms!Form1![Description] = strValue oAcc.Forms!Form1![Notes] = strNotes End if ' oAcc.Forms!Form1.NewRecord = True This works just fine for one record; I close out excel with the program and return to Access with the form filled in. However, now I'm trying to expand to calculate multiple rows of the same formulas and create a new record in Access for each row. From Access I would just run DoCmd.GoToRecord , , acNewRec but I don't know how to reference something like that from Excel. Any suggestions? On 26 Feb 2006 16:57:21 -0800, "super_dave_42" <super_dave_42@hotmail.com> wrote: oAcc.DoCmd.GoToRecord,,acNewRec -Tom. >I am searching for a way to create multiple records in Access 2000 from >a worksheet created in Excel. I'm pretty ...

Form editor for PHP GTK a la MS Visual Basic Editor?
I have (finally) gotten php-gtk working in Redhat Linux 9 with the instructions at: www.agata.org.br/us/install_pre.php Now I would like to know if some good tools (freeware or otherwise) exist to let me graphically create and edit forms (ie. with buttons, textboxes..etc), in a similar way that can be done in Microsoft Visual Basic editor. Thank you! Jack -----BEGIN PGP SIGNED MESSAGE----- Hash: SHA1 jack turer wrote: > I have (finally) gotten php-gtk working in Redhat Linux 9 with the > instructions at: www.agata.org.br/us/install_pre.php > > > Now I would like to know if some good tools (freeware or otherwise) > exist to let me graphically create and edit forms (ie. with buttons, > textboxes..etc), in a similar way that can be done in Microsoft > Visual Basic editor. > > Thank you! > > Jack Hi, You could try using some kind of WYSIWYG HTML editor (like Dreamweaver, although I'm not recommending this particular one), and design your form as you wish using tables. Then, simply copy and paste the HTML code into your PHP file. Chris -----BEGIN PGP SIGNATURE----- Version: GnuPG v1.2.4 (GNU/Linux) iD8DBQFBZK0OgxSrXuMbw1YRAmLaAJ9b5tm8eJSB8+4IP6hGOuFH4D7c0gCghscR mbETVGW9yC+lr/myZ2zp7LU= =fwxu -----END PGP SIGNATURE----- I think this might be different. GTK is the gimp tool kit API, for displaying windows on your own screen session (ie. nothing to do with web browsers, HTML, or anything about the internet). It is more like the ...

Moving object detection with a moving camera
Hi everyone, I need some help with my university project. It’s about dynamic object detection with a moving camera. I've installed a camera to a potentiometer. My inputs are thus the angular velocity of the camera and the accompanying picture. My idea was with the Computer Vision Toolbox "optical flow" to determine the speed and compare it with my camera speed, so to find out what objects have different speed as the camera itself. The results should be the dynamic objects. My question is what kind of speed (unit) is from the optical flow? I cannot find anything in the Mathwo...

Quick Basic to Visual Basic Converter
This is a multi-part message in MIME format. ------=_NextPart_000_000A_01C453DB.FEAF48A0 Content-Type: text/plain; charset="iso-8859-1" Content-Transfer-Encoding: quoted-printable Does anyone know of a utility that will aid in converting Quick Basic = code to Visual Basic code. I don't expect it would be perfect, but anything that would provide a = start on it would be helpful. Thanks ------=_NextPart_000_000A_01C453DB.FEAF48A0 Content-Type: text/html; charset="iso-8859-1" Content-Transfer-Encoding: quoted-printable <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN"> <HTML><HEAD> <META http-equiv=3DContent-Type content=3D"text/html; = charset=3Diso-8859-1"> <META content=3D"MSHTML 6.00.2800.1400" name=3DGENERATOR> <STYLE></STYLE> </HEAD> <BODY bgColor=3D#ffffff> <DIV><FONT size=3D2>Does anyone know of a utility that will aid in = converting=20 Quick Basic code to Visual Basic code.</FONT></DIV> <DIV><FONT size=3D2>I don't expect it would be perfect, but anything = that would=20 provide a start on it would be helpful.</FONT></DIV> <DIV><FONT size=3D2>Thanks</FONT></DIV></BODY></HTML> ------=_NextPart_000_000A_01C453DB.FEAF48A0-- Hmmm. Other than changes in several of the graphics methods (like CurrentX/Y versus Locate) and maybe the keyboard Get/Input they're pr...

Port Visual Basic to Visual Prolog
I'm trying to port the following Visual Basic program fragment to Visual Prolog 6.1 It opens the serial port for communications, sends a break command, switches to a specific speed, sends another command, then switches speed again, and starts listening. Any signal coming in is detected with the OnCom and displayed on the screen. This is so totally beyond my Visual Prolog skills that I have no clue how to even start porting it to Visual Prolog 6.1 Any help is appreciated!! Merel Private Sub Command1_Click() 'enable communications MSComm1.PortOpen = True &#...

Writing Visual Basic 6.0 forms and controls into Win32 resource files (.res. rc)
I would like to save forms and controls of a Visual Basic 6.0 OCX library (contains 21 controls) into Win32 resource files (.rc, .res) to give these resource files (satellite DLLs) to translators (Asian languages). The translator then sees the dialogs and is able to adapt the size of the controls adequate to the length of the strings in the languages. One solution for this problem ist the tool TsiWin32Dialog.dll from Michael S. Kaplan supplied on the CD to his book "Internationalization with Visual Basic". An Add-in writes all VB intrinsic controls into an resource file (with mapping of VB controls to Win32 controls) and additional code modules load the resource files during runtime and resize and redraw the VB forms and controls due to the information from the resource file. But this tool fails in two ways with my application. It would be fine to have the source code to fix a bug and enhance it to support UniToolbox controls. I asked the author by mail but he didn't answer. Is the source code of TsiWin32Dialog.dll public available any where? Does anyone know another tool with this functionality? Thank you for any help. Klaus On Mon, 24 May 2004 11:55:56 +0200, "Klaus Woersdoerfer" <topmandrill@hotmail.com> wrote: >I would like to save forms and controls of a Visual Basic 6.0 OCX library >(contains 21 controls) into Win32 resource files (.rc, .res) to give these >resource files (satellite DLLs) to translators (Asian languages)....

How to call a function located in a form module (form open in form view) from an Access Basic global module?
I would like to call a function stored in a form module in Access 2.0 from an Access 2.0 procedure in a global module. Function EmailTheOutletters () in module AppSpecific... .... 560 SSNtext = SelectRandomSSNtext(SSN) .... End Function SelectRandomSSNtext() is the procedure in the form module. I would use the syntax shown in line #560 if I were calling the function from within another procedure inside the form module. Do I have to reference it any differently if calling it from outside the form module? I don't think this is possible with Access 2.0 Solution: Put your function in a global module, and you can access it = from everywhere. --=20 Hope this helps Arno R "MLH" <CRCI@NorthState.net> schreef in bericht = news:53ch519mm1rhbojc8e8sav99t24v5roufm@4ax.com... >I would like to call a function stored in a form module > in Access 2.0 from an Access 2.0 procedure in a global > module. >=20 > Function EmailTheOutletters () in module AppSpecific... > ... > 560 SSNtext =3D SelectRandomSSNtext(SSN) > ... > End Function >=20 > SelectRandomSSNtext() is the procedure in the form module. > I would use the syntax shown in line #560 if I were calling the > function from within another procedure inside the form module. > Do I have to reference it any differently if calling it from outside > the form module? <snip> >I don't think this is possible with Access 2.0 >Solution: Put your function in a glo...

US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288557613)
US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288557613) ============================================================================================= Position: Sr. SW Eng. Reference: SMC01200 Location: Huntsville AL Duration: Perm Skills: 5+ years in development of Microsoft Windows applications using Microsoft tools and technologies such as Visual Basic, Visual C++, Visual Studio.NET and C#. Must be proficient in the use of Microsoft Office applications (Word, Excel, PowerPoint, Outlook, Internet Explorer and Access). UML Modeling (using Rational Rose) and CMM Level 3 activities. Development of aircraft mission planning and/or operation flight program (OFP) software. Please send your current resume in confidence to <staffing@eurosoft-inc.com> ..45288557613. ...

US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288832412)
US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288832412) ============================================================================================= Position: Sr. SW Eng. Reference: SMC01200 Location: Huntsville AL Duration: Perm Skills: 5+ years in development of Microsoft Windows applications using Microsoft tools and technologies such as Visual Basic, Visual C++, Visual Studio.NET and C#. Must be proficient in the use of Microsoft Office applications (Word, Excel...

US-AL-Huntsville: SW Engineer, Visual Basic, Visual C++, Visual Stdio.NET, C#; P (45288546624)
US-AL-Huntsville: SW Engineer, Visual Basic, Visual C++, Visual Stdio.NET, C#; P (45288546624) ============================================================================================== Position: SW Engineer Reference: SMC01201 Location: Huntsville AL Duration: Perm Skills: 5 + years development of MS Windows applications using Visual Basic, Visual C++, Visual Studio.NET and C#. Proficient in Microsoft Office applications (Word, Excel, PowerPoint, Outlook, Internet Explorer and Access). UML modeling experience using Rational Rose and CMM processes. Background in the development of aircraft mission planning for either the Air Force or Army and/or operation flight program (OFP) software. Please send your current resume in confidence to <staffing@eurosoft-inc.com> ..45288546624. ...

US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288557613)
US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45288557613) ============================================================================================= Position: Sr. SW Eng. Reference: SMC01200 Location: Huntsville AL Duration: Perm Skills: 5+ years in development of Microsoft Windows applications using Microsoft tools and technologies such as Visual Basic, Visual C++, Visual Studio.NET and C#. Must be proficient in the use of Microsoft Office applications (Word, Excel...

Newbie question: Quick Basic to Visual Basic
Program migration from Quick Basic to Visual Basic ? Regards to the newsgroup. Excuse my sudden intromission into the group, but I know from my long experience in these groups that there are a lot of people willing to help. As I ceased to program several years ago I found myself in the situation that my old programs are incompatible with Windows 98 and XP. I have code written in 1995 to 97 under DOS, using Quick Basic, which running under Windows, create problems when they write data files on to the fixed disk. I'm having trouble when restarting my PC. I guess this is due to the protection of the fixed disk by Windows. Mi question is: Is there a way of importing or converting my old codes into Visual Basic ? or Shall I have to write them again ? Thanks in advance. Juan Vazquez P.S.: I'm having the same problem with Borland Turbo Pascal and DELPHI. Is there a way of importing or converting my old Pascal programs into DELPHI ? "Juan Vazquez" <j.vazquez@_emavenca.com> wrote in message news:cu69ov$t5o$1@newsreader.mailgate.org... > > > > Program migration from Quick Basic to Visual Basic ? > > Regards to the newsgroup. > > Excuse my sudden intromission into the group, but I know from my long > experience in these groups that there are a lot of people willing to help. > > As I ceased to program several years ago I found myself in the situation > that my old programs are incompatible with Window...

Quick-Basic running in a Visual Basic compilation?
Hi everybody, I have a program, developed in Quick Basic under DOS, which are quite complicated and I wish to translate into Visual Basic, since Basic is more familiar for me than other languages. The question is how to write Quick Basic code in a Visual Basic program. It handles I/O commands and direct access to memory addresses for a A/D card. I have to say that this program works fine in a DOS window under Win98, but it's not the case for W2000/XP. Any comment will be highly appreciated. / Bish "Bishop" <Donottry@never.de> wrote in message news:c14po4$1efl2s$1@ID-145933.news.uni-berlin.de... > Hi everybody, > > I have a program, developed in Quick Basic under DOS, which are quite > complicated and I wish to translate into Visual Basic, since Basic is more > familiar for me than other languages. > The question is how to write Quick Basic code in a Visual Basic program. It > handles I/O commands and direct access to memory addresses for a A/D card. > I have to say that this program works fine in a DOS window under Win98, but > it's not the case for W2000/XP. > Any comment will be highly appreciated. I'll say you're in for a bit of work! Your program must be completely re-structured. VB is Event-driven, and doesn't like top-town and procedural code at all. THis, in it self isn't neccessarily a show-stopper, as long as your QB code is reasonably structured, but the *big* problem here, is the I/O and...

US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45289157610)
US-AL-Huntsville: Sr. SW Eng., Visual Basic, Visual C++, Visual Studio.NET, C#; (45289157610) ============================================================================================= Position: Sr. SW Eng. Reference: SMC01200 Location: Huntsville AL Duration: Perm Skills: 5+ years in development of Microsoft Windows applications using Microsoft tools and technologies such as Visual Basic, Visual C++, Visual Studio.NET and C#. Must be proficient in the use of Microsoft Office applications (Word, Excel...

Web resources about - detecting when a form is moved. - comp.lang.basic.visual.misc

Methods of detecting exoplanets - Wikipedia, the free encyclopedia
Any planet is an extremely faint light source compared to its parent star . In addition to the intrinsic difficulty of detecting such a faint ...

Detecting unauthorized cross-app resource access on OS X
Last week, Luyi Xing, a Ph.D. student from Indiana University Bloomington and his colleagues released a research paper on several vulnerabilities ...

METAL DETECTING A RARE SAXON COIN OF BURGRED - YouTube
ON A LARGE FORTY ACRE FIELD I MANAGED TO DETECT A RARE SAXON PENNY OF THE MERCIAN KING BURGRED. If you look at the coin close up you will see ...

Gold Coast Suns detecting 'a trickle of respect'
... produce a quarter "as good as we've played" in its first win at Etihad Stadium at the weekend Gold Coast chief executive Travis Auld is detecting ...

Detecting APT Activity with Network Traffic Analysis
Computerworld Australia is the leading source of technology news, analysis and tools for IT decision makers, managers and professionals.

Malware-detecting 'sandboxing' technology no silver bullet - Palo Alto, mcafee, trend micro, security ...
The security technology called "sandboxing" aims at detecting malware code by subjecting it to run in a computer-based system of one type of ...

Researchers close to developing a blood test for detecting Alzheimer’s
A team of scientists say they are getting closer to detecting Alzheimer’s antibodies at the preclinical stage, giving patients an opportunity ...

Threat-detecting surveillence cameras among first start-up projects to benefit from local Microsoft Innovation ...
South Australia's start-up support initiatives give funding to system that foils armed hold-ups by locking the shop doors to suspicious people. ...

Detecting APT Activity with Network Traffic Analysis
Defining Technology for Australia's IT Leaders.

Shrimp's eyes inspire new cancer-detecting camera
Shrimps' eyes have been revealed as the latest weapon against cancer, with their unique vision set to be adapted to diagnostic cameras.

Resources last updated: 3/24/2016 10:43:51 PM