f



Get Input for Password ??

Dear Friends

    I need a 'Get' input format picture for a Password being typed-in.

    I wish asterisks (i.e. stars) to show as the user is typing in his
password.

    Is there an easy way to do this ???

TIA,

-Mel Smith


0
5/26/2007 6:47:39 PM
comp.lang.clipper 3959 articles. 0 followers. Post Follow

14 Replies
779 Views

Similar Articles

[PageSpeed] 46

Mel Smith wrote:
>     I need a 'Get' input format picture for a Password being typed-in.
> 
>     I wish asterisks (i.e. stars) to show as the user is typing in his
> password.

Hi Mel

This works in clipper & xHarbour

/*
  * Password GET - echoing asterisks
  *
  * Compile: clipper getpass /m/n
  * Link   : rtlink fi getpass
  */

#include "Getexit.ch"
#include "Inkey.ch"
/*
  * Definition of GET PASSWORD command.
  */
#command @ <row>, <col> GET <var>                                ;
                         [<clauses,...>]                          ;
                         PASSWORD                                 ;
                         [<moreClauses,...>]                      ;
                                                                  ;
       => @ <row>, <col> GET <var>                                ;
                         [<clauses>]                              ;
                         SEND reader := {|oGet|                   ;
                                         GetPassword(oGet) }      ;
                         [<moreClauses>]

FUNCTION Main

LOCAL cVar1 := Space(10), ;
       cVar2 := Space(15), ;
       cVar3 := Space(12)

LOCAL GetList := {}

   CLEAR SCREEN
   @ 10, 10 SAY "Enter cVar1" GET cVar1 PASSWORD PICTURE "XXX-XXX-XXXX"
   READ

RETURN NIL


Procedure GetPassword( oGet )

LOCAL nKey,              ;
       nChar,             ;
       cKey

   // read the GET if the WHEN condition is satisfied
   IF ( GetPreValidate(oGet) )
     // activate the GET for reading
     oGet:SetFocus()

     oGet:cargo := ""
     DO WHILE ( oGet:exitState == GE_NOEXIT )
       // check for initial typeout (no editable positions)
       IF ( oGet:typeOut )
         oGet:exitState := GE_ENTER
       ENDIF

       // apply keystrokes until exit
       DO WHILE ( oGet:exitState == GE_NOEXIT )
         nKey := InKey(0)
         IF nKey >= 32 .AND. nKey <= 255
           oGet:cargo += Chr(nKey)
           GetApplyKey(oGet, Asc("*"))
            ELSEIF nKey == K_BS
           oGet:cargo := Substr(oGet:cargo, 1, Len(oGet:cargo) - 1)
           GetapplyKey(oGet, nKey)
         ELSEIF nKey == K_ENTER
           GetApplyKey(oGet, nKey)
         ENDIF
       ENDDO

       // disallow exit if the VALID condition is not satisfied
       IF ( !GetPostValidate(oGet) )
         oGet:exitState := GE_NOEXIT
       ENDIF
     ENDDO
     // de-activate the GET
     oGet:KillFocus()
   ENDIF
   IF oGet:exitState != GE_ESCAPE
     oGet:varPut(oGet:cargo)
   ENDIF

RETURN
0
arcadia21 (42)
5/26/2007 7:49:45 PM
In article <5brdlpF2t602fU1@mid.individual.net>
           medsyntel@aol.com "Mel Smith" writes:

> Dear Friends
> 
>     I need a 'Get' input format picture for a Password being typed-in.
> 
>     I wish asterisks (i.e. stars) to show as the user is typing in his
> password.
> 
>     Is there an easy way to do this ???
> 
> TIA,
> 
> -Mel Smith

Hi Mel,
Here's the function I used to use (S'87) for accepting a user-ID 
and password:

-----------------------------------------------------
  FUNCTION   ReadAt
  PARAMETERS yy, xx, maxlen, echo
  *
  * See S'87 manual, Appendix J-9 for more details
  *
  PRIVATE    char, string
  
  STORE "" TO char, string
  
  @ yy, xx  SAY  SPACE (maxlen)
  @ yy, xx  SAY  ""
  
  DO WHILE .t.
     char = INKEY (10)
     DO CASE
        CASE char == 0    && timeout - convert to ESC for LASTKEY
             KEYBOARD CHR (27)
             INKEY (0)
             EXIT
  
        CASE char == 13 .OR. char == 27   && <Return> or <Esc>
             EXIT
  
        CASE char > 32 .AND. char < 127
             IF maxlen == 0               && buffer full
                TONE (300, 1)
                LOOP
             ENDIF
  
             @ ROW(), COL()  SAY  IIF (echo, CHR (char), '*')
             string = string + CHR (char)
             maxlen = maxlen - 1
  
        CASE (char == 8 .OR. char == 19) .AND. (LEN (string) > 0)
             @ ROW(), COL() - 1 SAY " "
             @ ROW(), COL() - 1 SAY ""
             string = SUBSTR (string, 1, LEN (string) - 1)
             maxlen = maxlen + 1
  
     OTHERWISE          && some invalid key pressed
             TONE (300, 1)
  
     ENDCASE
  ENDDO
  
  RETURN string
-----------------------------------------------------
  
It is then called like:

  userID = ReadAt( 5, 10, 12, .T. )
  passwd = ReadAt( 6, 10, 12, .F. )

adjusting the screen coords and string lengths to suit.  It's up 
to you to set up colours etc. before calling.

Hope it helps,

Pete
-- 
   "We have not inherited the earth from our ancestors,
    we have borrowed it from our descendants."
0
pete11 (328)
5/27/2007 6:32:21 AM
Bill & Pete,

    Thanks for your suggestions !

    I'll give them a try tomorrow (am tired from golf now :(( )

-Mel


0
5/27/2007 9:35:50 PM
Hello,

> Dear Friends

>     I need a 'Get' input format picture for a Password being typed-in.

>     I wish asterisks (i.e. stars) to show as the user is typing in his
> password.

>     Is there an easy way to do this ???

GETSECRET() from CA-Tools



-- 
Regards
Jarek

(cut 'wytnijto' from mail address)

0
5/28/2007 5:44:01 AM
Jarek said:
> GETSECRET() from CA-Tools

Jarek:

    I'll look at getsecret() too !

Thanks,

-Mel Smith


0
5/28/2007 2:05:41 PM
"Mel Smith" <medsyntel@aol.com> wrote in message 
news:5brdlpF2t602fU1@mid.individual.net...
> Dear Friends
>
>    I need a 'Get' input format picture for a Password
>  being typed-in.
>
>    I wish asterisks (i.e. stars) to show as the user is
> typing in his password.
>
>    Is there an easy way to do this ???

http://www.the-oasis.net/ftpmaster.php3?content=ftpgenrl.htm
.... clave.zip
.... dots11.zip (may be able to change to "*")
.... pass.zip

David A. Smith 


0
dlzc (189)
5/28/2007 6:50:05 PM
David, Jarek, Bill & Pete:

    I have implemented Bill Robertson's suggestion and it works nicely
except:

    1.    A codeblock associated with a 'Valid' clause does not seem to get
the value of the input string passed to it -- at least when the 'password'
get is at the end of a set of 'gets'

    Repair: Remove the valid clause and put it into after the input and READ
is complete.


    2.    The <Esc> key is inoperative in the getpassword() function.

    Repair:
        Change the line:
            ELSEIF nKey == K_ENTER
        to
            ELSEIF nKey == K_ENTER .OR. nKey == K_ESC




0
5/28/2007 11:31:21 PM
Bill:

    Below is your test program slightly modified (addition of a 'Valid'
clause and some test code.

    This mod illustrates how the password vrbl (cVar1) is obscured inside
the Valid Clause, but shows up correctly after the 'Read' is completed.

    All I did was moved the Valid function below the read.

    Is this crazy or what , (or am I ) ??

-Mel Smith

****** clip here *****

/*
  * Password GET - echoing asterisks
  *
  * Compile: clipper getpass /m/n
  * Link   : rtlink fi getpass
  */

#include "Getexit.ch"
#include "Inkey.ch"
/*
  * Definition of GET PASSWORD command.
  */
#command @ <row>, <col> GET <var>                                ;
                         [<clauses,...>]                          ;
                         PASSWORD                                 ;
                         [<moreClauses,...>]                      ;
                                                                  ;
       => @ <row>, <col> GET <var>                                ;
                         [<clauses>]                              ;
                         SEND reader := {|oGet|                   ;
                                         GetPassword(oGet) }      ;
                         [<moreClauses>]

FUNCTION Main

LOCAL cVar1 := Space(10), ;
      cVar2 := Space(15), ;
      cVar3 := Space(12)

LOCAL GetList := {}

   CLEAR SCREEN
   @ 08, 10 SAY "Enter cVar2 : "  GET cVar2 PICTURE "XXXXXXXXXXXXXXX"
   @ 10, 10 SAY "Enter cVar1 :  "
   // Simply Add a VALID Clause to the Statement Below
   @ 10,COL() GET cVar1 PASSWORD PICTURE "XXX-XXX-XXXX" ;
            VALID {||CHKVARVALS(cVar2,cVar1)}
   READ
   @ 12, 10 SAY "Values after 'READ' Below"
   @ 14, 10 SAY "cVar1="+cVAR1
   @ 16, 10 SAY "cVar2="+cVar2

   INKEY(0)

RETURN NIL

Function CHKVARVALS(cV2,cV1)
   @ 12, 50 SAY "Values in VALID below:"
   @ 14, 50 SAY "cVar1="+cV1
   @ 16, 50 SAY "cVar2="+cV2

@ 20,01 SAY "Press Any Key"
INKEY(0)
@ 20,00

RETURN .T.


Procedure GetPassword( oGet )

LOCAL nKey,              ;
       nChar,             ;
       cKey

   // read the GET if the WHEN condition is satisfied
   IF ( GetPreValidate(oGet) )
     // activate the GET for reading
     oGet:SetFocus()

     oGet:cargo := ""
     DO WHILE ( oGet:exitState == GE_NOEXIT )
       // check for initial typeout (no editable positions)
       IF ( oGet:typeOut )
         oGet:exitState := GE_ENTER
       ENDIF

       // apply keystrokes until exit
       DO WHILE ( oGet:exitState == GE_NOEXIT )
         nKey := InKey(0)
         IF nKey >= 32 .AND. nKey <= 255
           oGet:cargo += Chr(nKey)
           GetApplyKey(oGet, Asc("*"))
            ELSEIF nKey == K_BS
           oGet:cargo := Substr(oGet:cargo, 1, Len(oGet:cargo) - 1)
           GetapplyKey(oGet, nKey)
         ELSEIF nKey == K_ENTER
           GetApplyKey(oGet, nKey)
         ENDIF
       ENDDO

       // disallow exit if the VALID condition is not satisfied
       IF ( !GetPostValidate(oGet) )
         oGet:exitState := GE_NOEXIT
       ENDIF
     ENDDO
     // de-activate the GET
     oGet:KillFocus()
   ENDIF
   IF oGet:exitState != GE_ESCAPE
     oGet:varPut(oGet:cargo)
   ENDIF

RETURN



0
5/29/2007 2:51:15 PM
Bill:

    Also, when a 'WHEN' clause is included in the password 'Get', a crash
results at line 334 in the GETPREVALID() function.

    Stanger, and stranger (or maybe I have a faulty getsys.prg in my Clipper
5.2e directory ??)

-Mel Smith


0
5/29/2007 6:57:02 PM
Mel

>    Also, when a 'WHEN' clause is included in the password 'Get', a crash
> results at line 334 in the GETPREVALID() function.
>
>    Stanger, and stranger (or maybe I have a faulty getsys.prg in my Clipper
> 5.2e directory ??)

More likely an incomplete COMMAND structure, the WHEN/VALID aren't declared here unless the generic 
moreClauses is supposed to cover them without showing specifics
ie - the moreclauses line
#command @ <row>, <col> GET <var>                                ;
                         [<clauses,...>]                          ;
                         PASSWORD                                 ;
                         [<moreClauses,...>]
     => @ <row>, <col> GET <var>                                ;
                         [<clauses>]                              ;
                         SEND reader := {|oGet|                   ;
                                         GetPassword(oGet) }      ;
                         [<moreClauses>]

Have a look in the Grumpfish library for a password routine, I think there's also one in SuperLib.

-- 
CYA
Steve 


0
5/30/2007 12:46:00 AM
Stephen said:

> More likely an incomplete COMMAND structure, the WHEN/VALID aren't
declared here unless the generic
> moreClauses is supposed to cover them without showing specifics
> ie - the moreclauses line
> #command @ <row>, <col> GET <var>                                ;
>                          [<clauses,...>]                          ;
>                          PASSWORD                                 ;
>                          [<moreClauses,...>]
>      => @ <row>, <col> GET <var>                                ;
>                          [<clauses>]                              ;
>                          SEND reader := {|oGet|                   ;
>                                          GetPassword(oGet) }      ;
>                          [<moreClauses>]

Stephen:

    Thanks for the above comments. however, the 'Valid' clause itself works
(but incorrectly)

-Mel


0
5/30/2007 2:20:18 PM
"Mel Smith" <medsyntel@aol.com> wrote in message 
news:5c5fgeF2v9qf8U1@mid.individual.net...
> Stephen said:
>
>> More likely an incomplete COMMAND structure, the WHEN/VALID aren't
> declared here unless the generic
>> moreClauses is supposed to cover them without showing specifics
>> ie - the moreclauses line
>> #command @ <row>, <col> GET <var>                                ;
>>                          [<clauses,...>]                          ;
>>                          PASSWORD                                 ;
>>                          [<moreClauses,...>]
>>      => @ <row>, <col> GET <var>                                ;
>>                          [<clauses>]                              ;
>>                          SEND reader := {|oGet|                   ;
>>                                          GetPassword(oGet) }      ;
>>                          [<moreClauses>]
>
> Stephen:
>
>    Thanks for the above comments. however, the 'Valid' clause itself works
> (but incorrectly)
>
> -Mel
>
Hi Mel

I've been out of town and didn't have access to the newsgroup. You are 
correct that the valid clause works as does any other clipper clause. The 
problem is that the main program hides the getlist by making it local to 
main. The real value is stored in the cargo slot until the enter key is 
pressed. That's the reason you get the output you do. I have modified your 
file so that you can get the value you want. I also added a when clause so 
you can see that it works as well. I made the getlist private so that it is 
available to your chkvarvals function. Your get cVar1 is on the tail of the 
getlist so you can use the tail function to index into the getlist or you 
can just use GetList[2] to get the same value as shown in the mod.

/*
  * Password GET - echoing asterisks
  *
  * Compile: clipper getpass /m/n
  * Link   : rtlink fi getpass
  */

#include "Getexit.ch"
#include "Inkey.ch"
/*
  * Definition of GET PASSWORD command.
  */
#command @ <row>, <col> GET <var>                                ;
                         [<clauses,...>]                          ;
                         PASSWORD                                 ;
                         [<moreClauses,...>]                      ;
                                                                  ;
       => @ <row>, <col> GET <var>                                ;
                         [<clauses>]                              ;
                         SEND reader := {|oGet|                   ;
                                         GetPassword(oGet) }      ;
                         [<moreClauses>]

FUNCTION Main

LOCAL cVar1 := Space(10), ;
      cVar2 := Space(15), ;
      cVar3 := Space(12)
PRIVATE GetList:= {}

   CLEAR SCREEN
   @ 08, 10 SAY "Enter cVar2 : "  GET cVar2 PICTURE "XXXXXXXXXXXXXXX"
   @ 10, 10 SAY "Enter cVar1 :  "
   // Simply Add a VALID Clause to the Statement Below
   @ 10,COL() GET cVar1;
              VALID CHKVARVALS(cVar2,cVar1);
              PASSWORD PICTURE "XXX-XXX-XXXX";
              when !empty(cVar2)

   READ
   @ 12, 10 SAY "Values after 'READ' Below"
   @ 14, 10 SAY "cVar1="+cVAR1
   @ 16, 10 SAY "cVar2="+cVar2

   INKEY(0)

RETURN NIL

Function CHKVARVALS(cV2,cV1)

@ 10,50 say cV2
@ 11,50 say cv1
@ 12,50 say aTail(GetList):Cargo
@ 13,50 say GetList[2]:Cargo
RETURN .t.


Procedure GetPassword( oGet )

LOCAL nKey,              ;
       nChar,             ;
       cKey

   // read the GET if the WHEN condition is satisfied
   IF ( GetPreValidate(oGet) )
     // activate the GET for reading
     oGet:SetFocus()

     oGet:cargo := ""
     DO WHILE ( oGet:exitState == GE_NOEXIT )
       // check for initial typeout (no editable positions)
       IF ( oGet:typeOut )
         oGet:exitState := GE_ENTER
       ENDIF

       // apply keystrokes until exit
       DO WHILE ( oGet:exitState == GE_NOEXIT )
         nKey := InKey(0)
         IF nKey >= 32 .AND. nKey <= 255
           oGet:cargo += Chr(nKey)
           GetApplyKey(oGet, Asc("*"))
            ELSEIF nKey == K_BS
           oGet:cargo := Substr(oGet:cargo, 1, Len(oGet:cargo) - 1)
           GetapplyKey(oGet, nKey)
         ELSEIF nKey == K_ENTER
           GetApplyKey(oGet, nKey)
         ENDIF
       ENDDO

       // disallow exit if the VALID condition is not satisfied
       IF ( !GetPostValidate(oGet) )
         oGet:exitState := GE_NOEXIT
       ENDIF
     ENDDO
     // de-activate the GET
     oGet:KillFocus()
   ENDIF
   IF oGet:exitState != GE_ESCAPE
     oGet:varPut(oGet:cargo)
   ENDIF

RETURN


0
marydick2007 (131)
6/2/2007 3:03:49 AM
Hi Mel

After I pressed the send button, I realized that a safer method would be to 
just include the getlist[]:cargo value in the valid function. To check out 
this option you can just modify one statement in your original post.

>              VALID CHKVARVALS(cVar2,cVar1);

would become: VALID CHKVARVALS( cVar2, GetList[2]:cargo )

That should give you the real value of the password entry.


0
marydick2007 (131)
6/2/2007 3:16:14 AM
Bill,

    Thanks for the changes !!!

    I'll install them on Monday.

-Mel Smith



0
6/2/2007 2:06:53 PM
Reply:

Similar Artilces:

Getting User Input after getting Input from a file
Hey, I am having a problem with a program I am working on. Basically, the first part of the program gets input from a file using cin.getline. Then the second part, (still in the same main as the first part) needs to get input from the user, and I want to do this with cin.getline also. The problem I am getting, is when I run the program, the text if read in from the file correctly, but it seems to just skip over the cin.getline when I want to get input from the user. I think this is having something to do with the cin.getline still trying to read the file, and getting the EOF and returning null...

Clipper... Clipper... Clipper
I have just found some time to revive Clipper...Clipper...Clipper at http://cch4clipper.blogspot.com. Congrats! "CCH" <cch@karensoft.com.my> wrote in message news:cf6fd8de-9e6a-468b-8dfe-b0b65e31f717@t26g2000prh.googlegroups.com... > I have just found some time to revive Clipper...Clipper...Clipper at > http://cch4clipper.blogspot.com. Hi Ron Thanx ! I am pretty surprised that there still active Clipperheads throughout the world as evidenced by the fact that Clipper... Clipper... Clipper now has visitors from over 46 countries in Europe, North America, Central Ame...

How to get the password input from user without echo it?
I am writing a script in common lisp now. It needs to ask the user to input the password. I can use (read-line) to do that, but it will echo user's password in the screen. How can I suppress the password echo? How can I suppress echo in GNU CLISP? On May 15, 10:09 am, Brian Jiang <brian...@gmail.com> wrote: > I am writing a script in common lisp now. It needs to ask the user to > input the password. I can use (read-line) to do that, but it will echo > user's password in the screen. How can I suppress the password echo? > How can I suppress echo in GNU CLISP? you c...

Clipper GET different than xHarbour GET
A client has pointed out a difference in the way Clipper handles a get with "@S" picture clause vs. xHarbour. Consider the following code snippet: func main local cData := "12345678901234567890" local cNext := " " clea @ 1,0 get cData pict "@S10" @ 2,0 get cNext read return During execution, if you move the cursor to the right in the first field beyond the first 10 characters so that it scrolls right and then press enter to position to the 2nd get field, the first field retains its display position in xHarbour, whereas in t...

How to get input from input devices (WindML)
Hi all I am trying to get input from mouse and keyboard using the default input message queue in an ML application. When I query the registry for the input service (to get the input service id) I get UGL_NULL returned, signalling that there is no such entry in the registry. I have configured VxWorks for Media Library as per the manual, and I have got simple graphics applications running, no problem. The Media Library is configured with a Pointer (PS/2 style pointer, device name /pointer/0) and a keyboard (PC Console, device name /pcConsole/1). I query the registry like this: UGL_INPUT_S...

get the input but still the input should remain
Hello, I know the subject line gives a little idea about the problem. Well, I want to get the input ,and after taking the input, I AGAIN want to get the same input. For Eg., Suppose input is 23: ../a.out 23 Now, I want to get 23, then store it in a variable and then again want to get the same input, i.e., 23. string strInput; cin>> strInput; int intInput; cin>> intInput; Both of them should be 23, ie, I should be able to get the input even if I have already taken this input. Thanks.-Prakhar On 2007-07-19 13:56, Prakhar wrote: > Hello, > I know the subject line gives...

Prompt user for input with password input
With the Express VI "prompt user for input" it is possible to have some inputs. But, when I need a text entry box as a password display, I have a problem. This option is not available. Or, am I wrong with this? As an Express VI, you don't have this option but if you right click on it and select Open Front Panel, the Express VI will be converted to a normal VI that you can modify and save. ...

How to get input from input devices (WindML) #2
Hi all I am trying to get input from mouse and keyboard using the default input message queue in an ML application. When I query the registry for the input service (to get the input service id) I get UGL_NULL returned, signalling that there is no such entry in the registry. I have configured VxWorks for Media Library as per the manual, and I have got simple graphics applications running, no problem. The Media Library is configured with a Pointer (PS/2 style pointer, device name /pointer/0) and a keyboard (PC Console, device name /pcConsole/1). I query the registry like this: UGL_INPUT_S...

How do I get my python program to get the root password ?
I want to make a python program that I can run as a normal user that changes the permission on some device files. It will need to ask me for the root password and then run chown as root in order to do this. How do I accomplish this (easily) ? Thanks On 2009-01-24, Linuxguy123 <linuxguy123@gmail.com> wrote: > I want to make a python program that I can run as a normal > user that changes the permission on some device files. It > will need to ask me for the root password and then run chown > as root in order to do this. > > How do I accomplish this (easily) ? The...

Redirect gets to get input from a file insted of from the us
I have this small program, or something like it as this just bigger: test.rb def testing t = gets puts t k = gets puts k end test2.rb testing When I run test2.rb it asks for user input. But I want the program to get this input from a file instead of asking the user. And I do not want to change the code in test.rb. I can only change the code in test2.rb or make new files, but I cant change test.rb I only now how to do this by running the program from the console ruby test2.rb < input.txt But that is not what I want. I want to do this inside the program. I do not want the user...

Clipper GET different than xHarbour GET when UPDATED() = .F.
I'm porting pretty big application from Clipper 5.3b to xHarbour 1.0.0. I have found one difference between Clipper and xHarbour. Look at the sample code: PROCEDURE test() CLS a := 1 / 3 @ 10,10 GET a PICTURE "@E 999,999.9" KEYBOARD CHR(13) // simulate user pressing Enter READ b := a * 3 @ 12,10 SAY b PICTURE "@E 999,999.99999" // in Clipper 5.3b you will see: 1,00000 // in xHarbour 1.000 you will see: 0,90000 RETURN In Clipper, when GET variable is not updated it retains it's precision, but in xHarbour it is rounded according to the PICTURE clause. It is ver...

After typing input of Integer it SKIPS getting the inputs of String.
Code: with ada.Text_IO; use ada.Text_IO; with ada.Integer_Text_IO; use ada.Integer_Text_IO; procedure Main is inputText: String (1..10); inputNmbr : Integer; StringNatural: Integer; begin Put_Line("Enter Integer"); Get(inputNmbr,1); Put_Line("Enter String"); Get_Line(inputText,StringNatural); Put_Line("==================="); Put("Input for Integer: "); Put(inputNmbr,1); Put_Line(""); Put_Line("Input for String: "); Put_Line(inputText(1..StringNatural)); end Main;...

Revival of Clipper...Clipper...Clipper
Hi I have just found some time to revive Clipper...Clipper...Clipper at http://cch4clipper.blogspot.com. CCH Hello Chee !!!!! What a surprise I can read you here just now! Hope everything are going well. -- Andi On Mon, 26 Jan 2009 00:50:50 -0800 (PST), ChongHwa.Chee@gmail.com wrote: >Hi > >I have just found some time to revive Clipper...Clipper...Clipper at >http://cch4clipper.blogspot.com. > >CCH On Jan 26, 5:48=A0pm, Andi Jahja <xharbour_thisisnotnee...@telkom.net.id> wrote: > Hello Chee !!!!! > > What a surprise I can read you here just now! > ...

gets gets
I'm a little surprised at this. In irb, I tried puts gets gets. Why? I don't know. but basically, gets gets, seems to almost act like a heredoc! myString = gets gets puts myString On Mar 26, 2007, at 3:17 AM, John Joyce wrote: > I'm a little surprised at this. > In irb, I tried puts gets gets. > Why? I don't know. > but basically, gets gets, seems to almost act like a heredoc! > myString = gets gets > puts myString It's not surprising at all. First, let's insert the parentheses so we can see it as Ruby does: puts(gets(gets())) Now we see th...

Web resources about - Get Input for Password ?? - comp.lang.clipper

Password strength - Wikipedia, the free encyclopedia
Password strength is a measure of the effectiveness of a password in resisting guessing and brute-force attacks. In its usual form, it estimates ...

California Employers, College Administrators Can’t Ask For Facebook Passwords
As the link between Facebook usage and work comes under closer scrutiny, several states have made it a law that employers cannot request social ...

Protecting Your Passwords and Your Privacy
Facebook and Privacy hat eine Notiz mit dem Titel Protecting Your Passwords and Your Privacy geschrieben. Du kannst den vollständigen Text hier ...

New Facebook Security Features: One-Time Passwords, Security Info
Facebook has launched two new security features to help users stay in control of their accounts. Users can now receive a one-time password from ...

The most popular passwords of 2015 are the worst, again
Our passwords are bad, and we should feel bad about it.

These are the worst passwords of 2015 are yours on the list? If so, change them now!
While it is easy to put someone down for engaging in poor security practices, remember not everyone grew up with computers. In other words, for ...

Widow wins battle with Apple over deceased husband’s password
A widow in Canada has won her battle with Apple after the tech giant demanded that she get a court order to obtain her deceased husband’s Apple ...

These were the 25 worst passwords of 2015
SplashData's annual "Worst Passwords List" highlights some not-so-secure choices that put people's data at risk

Worst, most common passwords for the last 5 years
Splashdata has again released its annual list of the most popular and therefore worst passwords found in over two million leaked passwords during ...

Secure your Notes with password protection in iOS 9.3
iOS 9.3 has a new feature that allows you to protect your sensitive Notes with a password or with Touch ID. It’s a great way to keep stuff like ...

Resources last updated: 1/28/2016 4:34:53 PM